// JOB    0C00 0001                0001 0001      ALGOL-D               03.2.702
// XEQ ALG                                                                      
*LIST                                                                           
*IOCS(1)                                                                        
*PRINT LINE                                                                     
*MAP                                                                            
*XREF                                                                           
*NAME SAMPLE PROGRAM                                                            
*NAME SAMPLE PROGRAM                                                            
'BEGIN'                                                                         
                                                                                
'COMMENT' DIESES PROGRAMM BERECHNET DIE ERSTEN FUENFZEHN ZEILEN DES             
          PASCAL DEIECHS UND UEBERTRAEGT SIE ZUR DATEI NR. 1 .,                 
                                                                                
   'INTEGER' L,K,N,I,M,POWERZEHN.,                                              
   'INTEGER''ARRAY' A(/0..19/).,                                                
   'BOOLEAN' C.,                                                                
                                                                                
   SYSACT(1,6,120).,  SYSACT(1,15,1).,                                          
   SYSACT(1,4,2).,    SYSACT(1,2,56).,                                          
   OUTSTRING(1,'('PASCAL DREIECK')').,                                          
                                                                                
   'FOR' L.=0 'STEP' 1 'UNTIL' 14 'DO'                                          
   'BEGIN'                                                                      
      SYSACT(1,4,2*L+5).,  SYSACT(1,2,58-3*L).,                                 
      A(/L/).= 1.,                                                              
      'FOR' K.= L-1 'STEP' -1 'UNTIL' 1 'DO'                                    
      A(/K/).= A(/K-1/) + A(/K/).,                                              
      'FOR' K.= 0 'STEP' 1 'UNTIL' L 'DO'                                       
      'BEGIN'                                                                   
         C.= 'TRUE'.,                                                           
         M.= A(/K/).,                                                           
         OUTSTRING(1,'(' ')').,                                                 
         'FOR' I.= 4 'STEP' -1 'UNTIL' 0 'DO'                                   
         'BEGIN'                                                                
            POWERZEHN.= 10 'POWER' I.,                                          
            N.= M'/'POWERZEHN.,                                                 
            M.= M-N*POWERZEHN.,                                                 
            'IF' N 'EQUAL' 0 'THEN'                                             
            'BEGIN'                                                             
              'IF' C 'THEN' OUTSYMBOL(1,'(' ')',1)                              
               'ELSE' OUTSYMBOL(1,'('0')',1)                                    
            'END'                                                               
            'ELSE'                                                              
            'BEGIN'                                                             
               C.= 'FALSE'.,                                                    
               OUTSYMBOL(1,'('123456789')',N).,                                 
            'END'                                                               
         'END'                                                                  
      'END'                                                                     
   'END'                                                                        
'END'                                                                           
/*                                                                              
// XEQ                                                                          
                                                                                
1---5----0----5----0----5----0----5----0----5----0----5----0----5----0--3++++++0

Anzahl Karten: 55